Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript - Гэри Розенцвейг

В этой игре пользователь может двигаться вперед и назад по буквам головоломки, используя клавиши со стрелками. Когда он нажимает клавишу с буквой, в карте букв выбранная буква заменяется на ту, клавиша которой нажата.

На рисунке 12.6 показана игра в процессе. Верхние буквы – это те, которые пользователь уже расшифровал. Нерасшифрованные буквы показаны звездочками. Нижние буквы – это зашифрованная фраза. Только верхние буквы меняются по мере разгадывания игроком головоломки.

Рисунок 12.6. В криптограмме нижние буквы – это зашифрованное послание, а верхние буквы меняются в зависимости от выбора игрока. Последняя буква в первой строке выделена полужирным шрифтом, поскольку это буква, которая только что выбрана

Подготовка ролика

На экране только два активных элемента, и то это два почти идентичных динамических текстовых поля. Первое, называющееся decryptedText, связано с переменной decrypted, оно чуть повыше чем второе, названное encryptedText и связанное с переменной encrypted. Шрифт второго поля также чуть светлее.

Оба текстовых поля используют шрифт Courier New, поэтому все буквы занимают одинаковое место, как в игре "Виселица".

Создание кода

Необычность этого ролика в том, что весь код помещается в сценарии одного кадра. Весь целиком. Нет ни единой кнопки или клипа. Библиотека этого ролика совершенно пуста.

Сценарий кадра начинается с вызова функции initGame. Она задает фразу и создает карту букв. Карта букв игрока вся состоит из звездочек, обозначающих каждую букву. Результатом должны стать звездочки вместо каждой буквы в расшифрованном текстовом поле.

Карта расшифровки, названная letterMap, задается вызовом функции createLetterMap. Вы также можете видеть еще не написанные функции showPhase и showCursor. Первая обновляет текстовое поле на экране, используя последнюю версию карт букв. Вторая выделяет только что выбранную букву полужирным шрифтом. Переменная charpos представляет, какая буква выбрана....

Примечание

Листенеры – это новое добавление версии Flash МХ. Листенер сообщает Flash, что событие произошло, и пора включать набор команд или функцию. Код может создать листенер, определив сначала стандартный объект. Событие, за которым должен следить листенер, в данном случае onKeyUp, задано так, что связано с функцией. Потом команда addListener присоединяет этот объект к объекту Flash, в данном случае объекту Key. Только определенные Flash объекты могут иметь листенеры, и эти листенеры могут быть использованы только для определенных событий, связанных с этими объектами. Например, листенер Key может следить только за событиями onKeyUp и onKeyDown.

В конце функции initGame создается листенер (прослушиватель) клавиатуры, который удостоверяется, что функция getLetter вызывается всякий раз, как игрок нажал клавишу.

initGame();

stop();

function initGame() {

// Используемая фраза.

phrase = "Imagination is more important than knowledge. – Albert Einstein";

// Определяем переменные.

createLetterMap();

userMap = "**************************";

charpos = 0;

// Показываем курсор и фразу.

showPhrase();

showCursor();

// Отслеживаем нажатие клавиши.

keyListener = new Object();

keyListener.onKeyUp = getLetter;

Key.addListener(keyListener);

}

Чтобы создать случайную карту букв, нужно просто перебрать все буквы и приписать новую, случайную букву к каждой букве алфавита. Однако это не так просто. Вам нужно быть уверенным не только в том, что вы взяли какую-нибудь букву, но также и в том, что раньше вы ее не брали. Например, вы не хотите приписать Р как к А, так и к Б.

Следующая сложность появляется, когда вы осознаете, что не хотели бы обозначить букву как саму себя. Таким образом, например, если Г обозначает Г, вы должны выкинуть эту карту и сделать новую.

Функция createLetterMap отрабатывает цикл, пока не найдет пригодную карту букв. Обычно это происходит с первой или со второй попытки.

// Создаем случайную строку.

function createLetterMap() {

do { // Повторяем, пока не будет найдена корректная карта.

letterMap = "";

for (var i=0;i<26;i++) {

do { // Повторяем пока не выбрана буква

r = Math.floor(Math.random()*26); //Случайное число.

c = String.fromCharCode(r+65); //Конвертируем в букву.

} while (letterMap.indexOf(c) > -1);

letterMap += c;

}

// Проверяем верность карты.

bad = false;

for(var i=0;i<26;i++) {

if (letterMap.charCodeAt(i) == i+65) {

bad = true; // Буква в разрешенной позиции.

break;

}

}

} while (bad);

}

Функция showPhrase просматривает фразу. Она прогоняет каждую букву через letterMap, чтобы получить зашифрованное значение. 3атем она прогоняет каждую зашифрованную букву через userMap, чтобы придать текущее, определенное пользователем, значение. Если знак является не буквой, а пробелом или знаком препинания, он показывается без зашифровки.

function showPhrase() {

encrypted = "";

decrypted = "";

for (var i = 0; i<phrase.length; i++) {

// Значение буквы в этой позиции.

c = phrase.toUpperCase().charAt(i);

if ((" .-,’").indexOf(c)>-1) {

// Задаем пустое место.

encrypted += c;

decrypted += c;

} else {

// Используем карту для поиска зашифрованной буквы.

encryptedChar = letterMap.charAt(c.charCodeAt(0)-65);

encrypted += encryptedChar;

// Используем вторую карту для поиска расшифрованной

// буквы.

decryptedCharacter = userMap.charAt(encryptedChar.charCodeAt(0)-65);

decrypted += decryptedCharacter;

}

}

}

Когда пользователь нажимает клавишу, листенер объекта Key вызывает функцию getLetter. Нажатая клавиша помещается в две переменные: ascii для ASCII-кода и code для кода клавиатуры. 3начения ascii используются для идентификации букв, а значения code – для идентификации клавишей со стрелками.

Если клавиши со стрелками нажаты, происходит обновление переменной charpos. В конце этой функции вызывается функция showCursor, и правильная буква выделяется полужирным шрифтом.

Если нажата буква, происходит обновление userMap, чтобы показать, что пользователь хочет поставить нажатую клавишу в соответствие с текущей закодированной буквой. Текстовое поле обновляется с помощью showPhrase. После этого расшифрованная фраза сравнивается с исходной, чтобы выяснить, насколько она ей соответствует.

function getLetter() {

// Считываем ascii код и код клавиатуры.

var ascii = Key.getAscii();

var code = Key.getCode();

// Передвигаем курсор.

if (code == Key.LEFT) {

charpos–;

if (charpos < 0) charpos = 0;

} else if (code == Key.RIGHT) {

charpos++;

if (charpos > phrase.length-1) charpos = phrase.length-1;

} else {

// Считываем клавиши.

var keyChar = String.fromCharCode(ascii);

keyChar = keyChar.toUpperCase();

// Убеждаемся, что была нажата буква.

if ((keyChar >= "A") and (keyChar <= "Z")) {

// Считываем символ из фразы.

phraseChar = phrase.toUpperCase().charCodeAt(charpos)-65;

// Если это буква.

if ((phraseChar >= 0) and (phraseChar < 26)) {

// Получаем ее значение в карте

letterNum = letterMap.charCodeAt(phraseChar)-65;

// Заменяем букву во второй карте.

userMap = replaceChar(userMap,letterNum,keyChar);

// Обновляем фразу

showPhrase();

//Проверяем, не окончена ли игра.

if (phrase.toUpperCase() == decrypted) {

gotoAndStop("game over");

}

}

}

}

// Обновляем курсор.

showCursor();

}

К сожалению, нет такой команды ActionScript, позволяющей легко заменять одну букву в строке на другую. Поэтому придется сделать для этого собственную функцию. Функция берет буквы до замены и присоединяет их к буквам после замены, с новой буквой в середине.

// Заменяем букву в строке.

function replaceChar(mainString, num, newchar) {

newString = mainString.substring(0,num)+newchar+mainString.substring(num+1,mainString.length);

return(newString);

}

Чтобы показать пользователю, к какой букве относится переменная charpos, эта буква выделяется полужирным и в зашифрованном, и в расшифрованном поле. Сделать это можно с помощью объекта типа TextFormat, появившегося в версии Flash МХ. Объекты TextFormat имеют множество свойств. Когда вы применяете формат текста к текстовому полю, в поле меняются только те свойства, которые были специально заданы в объекте. Объект plainFormat типа TextFormat обозначает только то, что полужирное выделение ошибочно. Таким образом, если он применен к текстовым полям decryptedText и encryptedText все полужирные буквы заменяются на обычные. Объект cursorFormat имеет противоположное действие. Все буквы, к которым он применен, становятся полужирными. Код устанавливает формат текста только одной буквы в поле, которая соответствует charpos.

function showCursor() {

// Оба поля устанавливаем невыделенным шрифтом.

plainFormat = new TextFormat();

plainFormat.bold = false;

decryptedText.setTextFormat(plainFormat);

encryptedText.setTextFormat(plainFormat);

// Одну букву выделяем полужирным.

cursorFormat = new TextFormat();

cursorFormat.bold = true;

decryptedText.setTextFormat(charpos,cursorFormat);

encryptedText.setTextFormat(charpos,cursorFormat);

}

К сведению

Исходный ролик содержит кадр «game over». Это к нему возвращается ролик, когда головоломка решена. Вы также можете использовать removeListener, если хотите заставить ролик перестать отвечать на нажатие клавиш.

Другие возможности

По мере того, как игрок движется вдоль фразы с помощью клавиш со стрелками, курсор иногда оказывается над пробелом или другим неактивным знаком. Вы можете расширить код, чтобы следить за движением курсора и, когда он находится на пустым пространством, заставить его продолжать движение вперед или назад, пока он не коснется буквы.