Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript - Гэри Розенцвейг

function removeAll() {

// Удаляем все клипы пуль.

for (i=0; i<bullets.length; i++) {

bullets[i].removeMovieClip();

}

// Удаляем все клипы астероидов.

for (i=0; i<rocks.length; i++) {

rocks[i].removeMovieClip();

}

}

К сведению

Как всегда, убедитесь, что для клипов в библиотеке установлены свойства связи, чтобы они были вкдючены в swf-файл. Свойства связи необходимо установить для астероидов и пуль, потому что до начала игры их нет на рабочем поле.

Я также создал три текстовых поля, отображаюших значения переменных gameLevel, lives и score. Эти поля расположены в разных углах экрана, над ними добавлен поясняюший текст.

Другие возможности

В таких играх, как «Астероид», можно придумать много интересного. Например, время от времени вокруг корабля может летать небольшой НЛО; если игрок его собьет, то заработает дополнительные очки. Зачастую корабль оснашен шитом, который зашишает его от определенного количества столкновений. Функция «Гиперпространство» переносит корабль в произвольную точку экрана, а «бомба» взрывает все астероиды, находящиеся на заданном расстоянии от корабля.

Это превосходная игра, в которой начинаюший программист ActionScript может попробовать свои силы и применить все имеюшиеся знания. Чем разнообразнее игра, тем лучше.

Погоня в лабиринте

Исходный файл: Mazechase.fla

Следуюшая игра – "Погоня в лабиринте" – классическая аркадная игра. Самое известное воплошение этой игры – Pac-Man.

В игре, фрагмент которой изображен на рис. 16.4, лиса бегает в лабиринте, пытаясь съесть все ягоды. Там же бегает злой кролик. Лиса должна не столкнуться с кроликом, пока не соберет все ягоды.

Рисунок 16.4. Лиса пытается собрать все ягоды, в то время как кролик стремится ее догнать

Задача проекта

Игра, приведенная в качестве примера, имеет самые важные отличительные черты игры-погони в лабиринте. Ягоды исчезают с экрана, если лиса проходит через место, где они находятся. Лиса может переместиться с одной стороны экрана на другую, войдя в туннель справа или слева. Если кролик догонит лису, то она теряет одну жизнь.

Подготовка ролика

В ролике Mazechase.fla всего лишь несколько библиотечных эталонов, основными из которых являются фон, лиса, кролик и ягода.

Создать фон просто, но делать это следует аккуратно. Представьте себе экран в виде сетки из квадратов со стороной 25 пикселов. Ягоды располагаются на всех пересечениях линий сетки, кроме тех, которые расположены на фоне, а не на дорожке лабиринта.

На рис. 16.5 представлен клип "background", для которого отображена сетка размером 25x25. Сетку можно изменить, выбрав пункт меню View → Grid → Edit Grid (Вид → Сетка → Редактировать).

Рисунок 16.5 . Когда в программе Flash отображена сетка, можно увидеть пересечения линий, на которых появятся ягоды

Сетка помогает быстро создать фон с помошью инструмента рисования прямоугольников. Для этого нужно обвести контуром некоторые области сетки и залить их цветом. Вы должны быть уверены, что границы фона немного перекрывают линии сетки. Когда программа будет помешать ягоды на пересечения линий сетки, они не появятся вдоль границы фона.

Первый кадр клипа "fox" – обычный статический кадр, в остальных кадрах представлена небольшая анимация – лиса съедает ягоду. Когда это происходит, клип воспроизводит второй кадр: игрок видит, как лиса ест ягоду, а затем клип возврашается к первому кадру.

В клипе "berry" два кадра: первый содержит изображение ягоды, а второй пустой. Когда лиса съедает ягоду, клип переходит ко второму кадру. Таким образом, клипы остаются на рабочем поле, но они видны до тех пор, пока ягода не будет съедена.

Клип "bunny" представляет собой анимацию: кролик всегда двигается, так что нет необходимости создавать статический кадр.

Все клипы, кроме "background", не будут видны до тех пор, пока не начнется ролик и программа не создаст их с помошью команды attachMovie.

В ролике содержатся практически такие же кадры, что и в ролике игры "Space Rocks": "start", "play", "lose life", "level over" и "game over".

Создание кода

В первом кадре содержится копия кнопки Play (Начать игру). Сценарий этого кадра не только переводит ролик к кадру «play», но и устанавливает несколько переменных.

on (press) {

lives = 3;

score = 0;

gameLevel = 1;

gotoAndPlay("play");

}

В кадре «play» содержится клип «actions» с прикрепленным к нему сценарием. Этот сценарий инициализирует все элементы в начале игры, после того как лиса теряет жизнь и перед началом нового уровня. Он также вызывает функции move и moveBunny для продолжения игры.

onClipEvent(load) {

// Инициализируем исходные элементы.

_root.startLevel();

}

onClipEvent(enterFrame) {

// Перемещаем лису.

_root.move();

// Перемещаем кролика.

_root.moveBunny();

}

Все функции этой игры можно найти в сценарии основной временной шкалы для кадра «play». Сначала идет функция startLevel.

Основная работа данной функции заключается в создании ягод. Для этого просматриваются все 15 положений по вертикали и 21 положение по горизонтали и проверяется, не расположены ли они поверх клипа "background". Если нет, то на пересечении линий сетки помешаются клипы "berry", а в массив berries добавляются указатели на эти клипы.

Также эта функция создает экземпляры клипов "fox" и "bunny", создает и устанавливает несколько новых свойств для каждого клипа, в том числе и dest (новое положение)....

Совет

Обратите внимание, что свойство dest для клипов «fox» и «bunny» представляет собой просто координату: {x:275, y:275}. Благодаря этому значительно упрощается обращение к данным величинам. Например, можно обратиться к новому горизонтальному положению клипа, записав fox.dest.x.

function startLevel() {

level = 0;

// Создаем ягоды.

berries = new Array();

// Ищем пересечения линий сетки.

for (y=1; y<16; y++) {

for (x=1; x<22; x++) {

// Выясняем, расположены ли пересечения поверх фона.

if (!(background.hitTest(x*25,y*25,true))) {

// Создаем и размещаем клип "berry".

attachMovie ("berry", "berry"+level, level);

clip = _root["berry"+level];

clip._x = x*25;

clip._y = y*25;

// Добавляем клип в массив berries.

berries.push(clip);

level++;

}

}

}

// Создаем клип с лисой и определяем его положение.

attachMovie("fox", "fox", level++);

fox._x = 275;

fox._y = 275;

// Определяем направление движения и координаты цели.

fox.move = {x:0; y:0};

fox.dest = {x:275, y:275};

fox.nextmove = 0;

// Создаем и размещаем клип с кроликом.

attachMovie("bunny", "bunny", level++);

bunny._x = 275;

bunny._y = 125;

// Определяем направление движения и координаты цели.

// Запоминаем координаты предыдущего положения.

bunny.move = {x:1, y:0};

bunny.dest = {x:300, y:125};

bunny.nextmove = 0;

bunny.last = {x:275, y:125};

}

В каждом кадре вызывается функция move, которая передвигает клип с лисой в соответствии с объектом move. В функции содержится специальное условие, чтобы можно было определить, перемешается ли лиса за пределы экрана справа или слева, и если да, то лиса появляется на противоположной стороне (по тоннелю лиса может переходить с одной стороны экрана на другую).

Новое положение цели как для лисы, так и для кролика – всегда координаты следующей ягоды. Даже если ягоду не видно, клип все равно находится на своем месте. Когда лиса доходит до ягоды, координаты которой совпадают со значениями объекта fox.dest, вызывается функция eatBerry, чтобы удалить ягоду, если она все еше видна. Затем с помошью функции nextMove определяются координаты следующего положения цели.

Обратите внимание, что лиса каждый раз перемешается на пять пикселов. Так как все ягоды расположены на расстоянии 25 пикселов друг от друга, то, чтобы дойти до следующей ягоды, необходимо сделать пять шагов. Скорость передвижения лисы – число, которое прибавляется к свойству nextMove. В данном случае добавляется число 50, то есть между шагами пройдет, по крайней мере, 50 миллисекунд.

function move() {

// Выясняем, можно ли сделать следующий шаг.

if (getTimer() > fox.nextmove) {

// Нельзя сделать следующий шаг в течение 50 миллисекунд.

fox.nextmove = getTimer() + 50;

// Перемещаем лису.

fox._x += fox.move.x*5;

fox._y += fox.move.y*5;

// Определяем, прошла ли лиса сквозь тоннель.

if (fox._x > 550) fox._x = 0;

if (fox._x < 0) fox._x = 550;

// Проверяем, достигла ли лиса положения своей цели.

if ((fox._x == fox.dest.x) and (fox._y == fox.dest.y)) {

eatBerry();

nextMove();

}

}

}

Для того чтобы лиса съела ягоду, нужно просмотреть массив berries и определить, совпадает ли положение какой-либо ягоды с положением лисы. Если да, то клип этой ягоды переходит ко второму кадру, ягода исчезает, а количество очков увеличивается. Так как в поисках нужной ягоды вы просматриваете массив berries, можете посчитать, сколько ягод не было съедено. Если была найдена не съеденная ягода, то уровень не заканчивается.

function eatBerry() {

// Предположим, что все ягоды были съедены.

allGone = true;

// Просматриваем массив berries.

for (i=0; i<berries.length; i++) {

// Выясняем, находится ли ягода там же, где и лиса.

if ((berries[i]._currentFrame == 1) and (berries[i]._x ==fox._x) and (berries[i]._y == fox._y)) {