Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript - Гэри Розенцвейг

onClipEvent (mouseDown) {

// Определяем, в каком месте пользователь щелкнул мышью.

x = _root._xmouse;

o = _root._ymouse;

// Проверяем, какое изображение лисы найдено.

for (i=0; i<7; i++) {

if (_root["fox"+i],hitTest(x, o, false)) {

// Изменяем цвет лисы.

myColor = new Color(_root["fox"+i]);

myColor.setTransform({rb:128,bb:0,gb:0});

// Запоминаем, что лиса найдена.

found[i] = true;

break;

}

}

// Проверяем, все ли лисы найдены.

gameover = true;

for (i=0; i<7; i++) {

if (found[i] == false) {

// Если хотя бы одна еще не найдена,

// игра не закончена.

gameover = false;

}

}

// Заканчиваем игру, если пользователь выиграл.

if (gameover) {

_root.gotoAndPlay ("Game Over");

}

}...

Примечание

Команда break используется в цикле for и других для его немедленной остановки. Это удобно, когда по той или иной причине необходимо остановить цикл. В вышеприведенном коде цикл проходит значения от 0 до 6, но может завершиться в случае, если функция hitTest примет значение true.

К сведению

Игра включает еще два кода кнопок Play, один для окна начала, другой для окна завершения игры. Кроме того, все кадры содержат команду stop(), запрещающую переход ролика к следующему кадру.

Выбор цвета найденных объектов зависит от фона. В нашем примере фон состоит из зеленого, коричневого и голубого цветов, поэтому для пойманных лис мы выбрали красный цвет.

Другие возможности

Приведенный здесь пример – игра для совсем маленьких детей. Тем не менее, используемый в ней принцип может быть использован при создании более совершенных игр.

Детям более старшего возраста подойдет игра, целью которой является нахождение чисел или слов какого-либо одного типа. К примеру, задача игры может состоять в выборе глаголов из имеющихся в наличии слов разных частей речи. Другой вариант – географическая викторина, в которой игроку необходимо выбрать определенные страны или места.

Поймай лису

Исходный файл: Whackfoxfla

Одна из игр в залах игровых автоматов прошлых лет называлась "Поймай крота". Игровое поле представляло собой плоскость, в отверстиях которой появлялись небольшие объекты, похожие на кротов. При помощи мягкого молотка, обычно привязанного к автомату, необходимо было ударять по кротам. Они появлялись нерегулярно и в случайном порядке, поэтому для игры была необходима хорошая реакция.

Существуют различные компьютерные варианты подобной игры, очень популярные в сети. Они построены по тому же принципу, что и игра "Поймай крота", хотя редко похожи на нее. Объекты появляются в случайных местах и в произвольное время, и игрок должен щелкнуть по ним, прежде чем они исчезнут.

На примере ролика Whackfox.fla мы рассмотрим более традиционный вариант этой игры. На рис. 8.3 изображена игровая область: бревно с 18 отверстиями. Время от времени из отверстия на одну-две секунды выглядывает лиса. Щелкнув по лисе, игрок получает очки.

Рисунок 8.3. Игровая область игры «Поймай лису» представляет собой бревно с 18 отверстиями. Лиса может появиться в любом из них

Задача проекта

Задача игры состоит в том, чтобы отверстие, в котором появляются объекты, выбиралось программой произвольным образом. Лиса может показаться в любом из 18 отверстий и почти сразу же исчезнуть.

На рис. 8.4 показан кадр анимации игры. В то время, когда лиса выглядывает, пользователь должен щелкнуть по ней и получить очки.

Игра ведется на время и счет.

Рисунок 8.4. Одна из лис выглянула из отверстия

Подход

Каждое отверстие в бревне представляет собой экземпляр одного клипа. Клип изображает либо пустое отверстие, либо анимацию лисы, выглядывающей из этого отверстия.

Другой клип под названием "actions" управляет очередностью и периодичностью воспроизведения клипов. В начале игры лисы будут выглядывать через каждые две секунды. С каждым разом интервал между появлениями лис немного сокращается.

Когда игрок щелкает по экрану, клип "actions" определяет, какая лиса была выбрана. После этого клип воспроизводит другую анимацию, изображающую лису в состоянии легкого шока.

Каждый раз при появлении лисы значение счетчика увеличивается на один пункт. Когда игрок попадает в лису, значение другого счетчика также увеличивается на единицу. Счет отображается следующим образом: количество попаданий в лису, потом знак /, затем количество появлений лисы. Другими словами, значение "5/12" будет обозначать, что игрок поразил 5 лис из 12.

Подготовка ролика

Имеющиеся 18 отверстий в бревне – это 18 копий одного клипа. Первый кадр данного клипа изображает обычное отверстие. Следующим элементом временной шкалы клипа является анимация лисы, ненадолго выглядывающей из отверстия и затем вновь исчезающей. Другая анимационная последовательность изображает попадание в лису и ее исчезновение. Она запускается, если пользователь успел щелкнуть по лисе (рис. 8.5).

Рисунок 8.5. Игрок только что поразил лису

Для того чтобы код мог управлять 18 клипами, им были присвоены имена от «fox0» до «fox17». Необходимо также создать динамическую текстовую область с именем showScore. На рис. 8.6 изображена панель Properties данной текстовой области.

Рисунок 8.6. Текстовая область связывается с переменной showScore в панели Properties

Создание кода

Весь код данной игры назначен клипу «actions», расположенному за пределами рабочего поля. Он начинается с инициализации всех глобальных переменных. В начале ролика интервал появления лис равен 2 секундам (2000 миллисекундам).

onClipEvent (load) {

// Указываем промежуток времени между появлениями лис.

timeBetweenFoxes = 2000;

// Определяем время до появления следующей лисы.

nextFox = getTimer() + timeBetweenFoxes;

// Инициализируем переменные пораженных и показанных лис.

score = 0;

numFoxes = 0;

}...

Примечание

Функция getTimer() – это своеобразные часы. Функция возвращает количество миллисекунд, прошедших после начала ролика. Значение этих часов постоянно увеличивается, поэтому данную функцию удобно использовать для управления временными интервалами в вашей игре.

Функция onClipEvent(enterFrame) определяет, наступило ли время для появления следующей лисы. Затем она выбирает такое новое отверстие, которое не используется в данный момент. Интервал времени между появлениями лис сокращается на 10 миллисекунд, в результате чего игра с каждым разом все больше ускоряется. Если значение интервала составляет менее 1000 миллисекунд, игра завершается. За 150 секунд пользователь получает 100 возможностей поразить лису.

onClipEvent (enterFrame) {

// Определяем, не пора ли показывать следующую лису.

if (getTimer() >= nextFox) {

// Сокращаем время между показами.

timeBetweenFoxes -= 10;

// Выясняем, не пора ли заканчивать игру.

if (timeBetweenFoxes < 1000) {

_root.gotoAndPlay("End") ;

// Если нет, показываем следующую лису.

} else {

// Увеличиваем счетчик показанных лис.

numFoxes++;

_root.showScore = score + "/" + numFoxes;

// Определяем, какая лиса покажется. while (true) {

while (true) {

fox = Int(Math.Random()*18);

if (_root["fox"+fox]._currentFrame == 1) break;

}

// Выбранная лиса появляется из отверстия.

_root ["fox"+fox].gotoAndPlay ("popup") ;

// Устанавливаем время появления следующей лисы.

nextFox = getTimer() + timeBetweenFoxes;

}

}

}

Следующая функция обрабатывает нажатия кнопки мыши пользователя. Здесь используется тот же самый прием, что и в игре «Найди лису»: программа проверяет клипы на попадание по ним при помощи функции hitTest. Также программа проверяет, воспроизводится ли анимационная последовательность, в которой лиса выглядывает из отверстия. Кадр 1 клипа является статическим и представляет собой простое отверстие. Кадры 2-24 – это анимация лисы, которую поразил пользователь. Пользователь может щелкнуть по лисе только во время анимации, в которой лиса выглядывает из отверстия (эта анимация начинается с кадра 25). Таким образом, если номер кадра больше, чем 24, щелчок разрешается. В противном случае он игнорируется.

onClipEvent (mouseDown) {

// Определяем, по какому месту щелкнул пользователь.

x = _root._xmouse;

o = _root._ymouse;

// Проверяем на попадание всех лис.

for (i=0;i<18;i++) {

// Проверяем только выглядывающих лис.

if (_root["fox"+i]._currentFrame > 24) {

// Выясняем, попал ли пользователь по лисе.

if (_root["fox"+i].hitTest(x,y,false)) {

// Воспроизводим анимацию, соответствующую попаданию.

_root["fox"+i].gotoAndPlay("whack");

// Увеличиваем количество очков.

score++;

_root.showScore = score + "/" + numFoxes;

}

}

}

}

К сведению

Как обычно, в некоторые места сценария необходимо добавить дополнительный код. В основной кадр, а также в кадры начала и завершения игры необходимо поместить команду stop(). В нашем примере эти кадры являются отдельными сценами.

Другие возможности

Имейте в виду, что клипы, изображающие лис, не обязательно должны быть одинаковыми. Сценарий реагирует только на метки «whack» (удар) и «popup» (выглядывающая лиса), а после 24 кадра еще и на начало анимации выглядывающей лисы. Вы можете использовать несколько клипов, изображающих разных лис. Необходимо лишь убедиться, что они достаточно похожи для того, чтобы код мог их обрабатывать, а также присвоить им соответствующие имена при размещении экземпляров клипов на рабочем поле. Использование различных лис сделает игру интереснее.